Thank you both for replying - I hope to pick up some additional comments in time.

If you are both on 2005 then you are correct not everything that can be extracted from .hkp is available in Automation. If we are talking about 2007.3+ then I am hard pressed to think of something that's not available in Automation.

A comment was made about the stability of Automation: It's our experience that it is very stable - we are huge consumers of Automation so we tend to shake out all the issues internally. I won't say there are zero defects but there are very few. If you discover an Automation defect I would encourage you to submit it - we work very aggressively to fix these defects.

Thanks, Ed

I see you are using the hidden, undocumented and unsupported, ReplayFile method on the document. There is a reason that it's hidden - it's designed for internal use, not for general use. :-)

If you want to drive the General Interfaces dialog there is an engine available in Automation Pro.

Regards, Ed

The methods on the General Interfaces object are described in the Automation Help document. Let me know if that is not sufficient and I will see if I can find you some additional information.

Regards, Ed

OH, the question is really about DXF Export and not about the General Interfaces dialog! The code in the above script searches for the "General Interfaces" dialog but I see that is bogus and those lines shouldn't be in the script. :-)

So to answer the question: DXF export is not currently available in the engines nor do I know when it will be available.

However, we might be able to do something with the existing Automation methods in conjunction with the DXF dialog. Take a look at this:

Option Explicit

Dim app: Set app=GetObject(,"MGCPCB.Application")
Dim doc: Set doc=app.ActiveDocument

call ValidateServer(doc)

' invoke the DXF export command

app.Gui.ProcessCommand("File->Export->DXF...")

' get a reference to this DXF dialog
Dim dlgObj: Set dlgObj = app.Gui.FindDialog("DXF Export")

' get a reference to the edit string which holds the output file name
Dim editbox: Set editbox = dlgObj.FindEditBox("DXF output file:")

' change name of output file
editbox.Text = "c:\esmith\Ed.dxf"

' find the OK button
dim OKButton: set OKButton = dlgObj.FindButton("OK")

' and press it to execute the dialog
call OKButton.Click

MsgBox "DXF Export done"

Private Function ValidateServer(doc)
    dim key, licenseServer, licenseToken

    ' Ask Expedition’s document for the key
    key = doc.Validate(0)

    ' Get license server
    Set licenseServer = CreateObject("MGCPCBAutomationLicensing.Application")

    ' Ask the license server for the license token
    licenseToken = licenseServer.GetToken(key)

    ' Release license server
    Set licenseServer = nothing

    ' Turn off error messages.  Validate may fail if the token is incorrect
    On Error Resume Next
    Err.Clear

    ' Ask the document to validate the license token
    doc.Validate(licenseToken)
    If Err Then
        ValidateServer = 0   
    Else
        ValidateServer = 1
    End If
End Function

The above script will bring up the DXF export dialog, load the last output scheme (controlled by the file \config\DXFSettings.txt in the job directory), change the output filename and press the OK button to get the DXF file generated. If you want a mechanism like this to generated a DXF file with the press of a button you must have a number of predefined scheme you output otherwise you would just use the dialog... So, you could generate your own scheme (or schemes) using the DXF dialog and store them in a central location. Then you could modify the above script to use the FileSystemObject to copy the scheme from the central location over the top of the existing config\DXFSettings.txt file before the dialog is invoked from the above script. This way the dialog will be prepopulated with the required scheme and the script will press the OK button and generate the DXF file with the contents specified by the scheme.

I hope this helps.

Regards, Ed