AnsweredAssumed Answered

Problem using SPICE simulation model of TI THS6052 in Hyperlynx Analog simulation

Question asked by nhd973 on Nov 20, 2018
Latest reply on Dec 4, 2018 by weston_beal

Hello,

PADS hyperlynx analog got an error when simulating THS6052 SPICE model at line ".MODEL Rtc RES TC1=-0.0055". The error is "..\..\sym\THS6052.mod(45): error -- res is an unknown model type."

Any suggestion to fix the problem?

I am running Hyperlynx Analog VX.2.4.

For reference, THS6052 SPICE model is listed below:

* THS6052

*****************************************************************************

* (C) Copyright 2011 Texas Instruments Incorporated. All rights reserved.                                           

*****************************************************************************

** This model is designed as an aid for customers of Texas Instruments.

** TI and its licensors and suppliers make no warranties, either expressed

** or implied, with respect to this model, including the warranties of

** merchantability or fitness for a particular purpose.  The model is

** provided solely on an "as is" basis.  The entire risk as to its quality

** and performance is with the customer.

*****************************************************************************

*

* This model is subject to change without notice. Texas Instruments

* Incorporated is not responsible for updating this model.

*

*****************************************************************************

*

** Released by: Analog eLab Design Center, Texas Instruments Inc.

* Part: THS6052

* Date: 08JUL2011

* Model Type: ALL IN ONE

* Simulator: PSPICE

* Simulator Version: 16.0.0.p001

* EVM Order Number: N/A

* EVM Users Guide: N/A

* Datasheet: SLOS293D - JUNE 2000 - REVISED DECEMBER 2001

*

* Model Version: 1.0

*

*****************************************************************************

*

* Updates:

*

* Version 1.0 :

* Release to Web

*

*****************************************************************************

* THS6052 SUBCIRCUIT

* CONNECTIONS:      NON-INVERTING INPUT

*                   | INVERTING INPUT

*                   | | POSITIVE POWER SUPPLY

*                   | | | NEGATIVE POWER SUPPLY

*                   | | | | OUTPUT

*                   | | | | |

*                   | | | | |

*                   | | | | |   

.SUBCKT THS6052     1 2 3 4 5   

*   

Q62          17   1  16 NPN_IN 0.625   

Q61          18   1  12 PNP_IN 0.625   

Q68          13  12   2 NPN_IN 0.625   

Q69          11  16   2 PNP_IN 0.625   

I8           17  12     DC 90u   

I10          16  18     DC 90u   

Q124         11  11  31 NPN 0.625   

Q125         32  32  15 NPN 1   

Q126         09  11  33 NPN 0.625   

Q127         13  13  35 PNP 0.625   

Q128         34  34  14 PNP 1

Q129         09  13  06 PNP 0.625

R386         18  15  50

R387         32  31  600

R388         32  33  600

R389         35  34  600

R390         06  34  600

R391         14  17  50

C80           0  09  2.25p

Q101         18  09  21 PNP 0.3

Q102         17  09  22 NPN 0.3

Q122         21  34  19 PNP 3

Q123         22  32  28 NPN 3

R385         18  28  60

R392         19  17  60   

Q93          50  30  18 NPN 4.51074419031202   

Q94          30  30  27 NPN 0.0902148838062404   

Q97          50  29  17 PNP 5.86396744740562   

Q98          29  29  26 PNP 3.60859535224962   

Q103         30  22  25 PNP 4   

Q104         29  21  24 NPN 2.2   

R367         50  24  50   

R366         25  50  50   

R356         26  17  50   

R352         18  27  50   

Lout    50   5 15n 

Cout    50  51 80p 

Rout       51   5 55.423227177666  

V43           4  18 0.15

V44          17   3 0.15

Rbias         3   4  Rtc 8k

.MODEL Rtc RES TC1=-0.0055

.MODEL NPN NPN

+ IS=170E-18 BF=100 NF=1 VAF=100 IKF=0.0389 ISE=7.6E-18

+ NE=1.13489 BR=1.11868 NR=1 VAR=4.46837 IKR=8 ISC=8E-15

+ NC=1.8 RB=250 RE=0.1220 RC=200 CJE=120.2E-15 VJE=1.0888 MJE=0.381406

+ VJC=0.589703 MJC=0.265838 FC=0.1 CJC=133.8E-15 XTF=272.204 TF=12.13E-12

+ VTF=10 ITF=0.147 TR=3E-09 XTB=1 XTI=5

.MODEL NPN_IN NPN

+ IS=170E-18 BF=400 NF=1 VAF=100 IKF=0.0389 ISE=7.6E-18

+ NE=1.13489 BR=1.11868 NR=1 VAR=4.46837 IKR=8 ISC=8E-15

+ NC=1.8 RB=10 RE=0.1220 RC=200 CJE=120.2E-15 VJE=1.0888 MJE=0.381406

+ VJC=0.589703 MJC=0.265838 FC=0.1 CJC=133.8E-15 XTF=272.204 TF=12.13E-12

+ VTF=10 ITF=0.147 TR=3E-09 XTB=1 XTI=5 KF=1.1E-14

.MODEL PNP PNP

+ IS=296E-18 BF=100 NF=1 VAF=100 IKF=0.021 ISE=494E-18

+ NE=1.49168 BR=0.491925 NR=1 VAR=2.35634 IKR=8 ISC=8E-15

+ NC=1.8 RB=250 RE=0.1220 RC=200 CJE=120.2E-15 VJE=0.940007 MJE=0.55

+ VJC=0.588526 MJC=0.55 FC=0.1 CJC=133.8E-15 XTF=141.135 TF=12.13E-12

+ VTF=6.82756 ITF=0.267 TR=3E-09 XTB=1 XTI=5

.MODEL PNP_IN PNP

+ IS=296E-18 BF=100 NF=1 VAF=100 IKF=0.021 ISE=494E-18

+ NE=1.49168 BR=0.491925 NR=1 VAR=2.35634 IKR=8 ISC=8E-15

+ NC=1.8 RB=10 RE=0.1220 RC=200 CJE=120.2E-15 VJE=0.940007 MJE=0.55

+  VJC=0.588526 MJC=0.55 FC=0.1 CJC=133.8E-15 XTF=141.135 TF=12.13E-12

+ VTF=6.82756 ITF=0.267 TR=3E-09 XTB=1 XTI=5 KF=1.1E-14

.ENDS

*End of model THS6052

Outcomes